+Show TOC
×Hide TOC

Rectangle

Kind of class:	class
Inherits from:	BaseShape < CoreObject
Version:	08/02/07
Author:	Aaron Clinger
Classpath:	org.casaframework.math.geom.Rectangle
File last modified:	Sunday, 19 August 2007, 13:43:31

► View source

▼ Hide source

/*
    CASA Framework for ActionScript 2.0
    Copyright (C) 2007  CASA Framework
    http://casaframework.org
    
    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Lesser General Public
    License as published by the Free Software Foundation; either
    version 2.1 of the License, or (at your option) any later version.
    
    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Lesser General Public License for more details.
    
    You should have received a copy of the GNU Lesser General Public
    License along with this library; if not, write to the Free Software
    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
*/

import org.casaframework.math.geom.BaseShape;
import org.casaframework.math.geom.Point;

/**
    Stores position and size of a rectangle (or square).

    @author Aaron Clinger
    @version 08/02/07
*/

class org.casaframework.math.geom.Rectangle extends BaseShape {
    
    
    /**
        Creates new rectangle object.
        
        @param x: The horizontal position of the rectangle.
        @param y: The vertical position of the rectangle.
        @param width: Width of the rectangle.
        @param height: <strong>[optional]</strong> Height of the rectangle. If <code>undefined</code> assumes <code>height</code> matches <code>width</code> (Creates square).
    */
    public function Rectangle(x:Number, y:Number, width:Number, height:Number) {
        super(x, y, width, height);
        
        this.$setClassDescription('org.casaframework.math.geom.Rectangle');
    }
    
    /**
        @return The right X position of the rectangle.
    */
    public function getX2():Number {
        return this.getX() + this.getWidth();
    }
    
    /**
        Sets the right position of the rectangle.
        
        @param x: The right X position of the rectangle.
    */
    public function setX2(x:Number):Void {
        this.setWidth(x - this.getX());
    }
    
    /**
        @return The bottom Y position of the rectangle.
    */
    public function getY2():Number {
        return this.getY() + this.getHeight();
    }
    
    /**
        Sets the bottom position of the rectangle.
        
        @param y: The bottom Y position of the rectangle.
    */
    public function setY2(y:Number):Void {
        this.setHeight(y - this.getY());
    }
    
    public function getPerimeter():Number {
        return this.getWidth() * 2 + this.getHeight() * 2;
    }
    
    public function getArea():Number {
        return this.getWidth() * this.getHeight();
    }
    
    public function containsPoint(pointObject:Point):Boolean {
        return pointObject.getX() >= this.getX() && pointObject.getX() <= this.getX2() && pointObject.getY() >= this.getY() && pointObject.getY() <= this.getY2();
    }
    
    /**
        Determines whether the rectangle specified in the <code>rectangleObject</code> parameter is equal to this rectangle object.
        
        @param rectangleObject: A defined {@link Rectangle} object.
        @return {@inheritDoc}
    */
    public function equals(rectangleObject:Rectangle):Boolean {
        return this.getX() == rectangleObject.getX() && this.getY() == rectangleObject.getY() && this.getWidth() == rectangleObject.getWidth() && this.getHeight() == rectangleObject.getHeight();
    }
    
    /**
        @return A new rectangle object with the same values as this rectangle.
    */
    public function clone():Rectangle {
        return new Rectangle(this.getX(), this.getY(), this.getWidth(), this.getHeight());
    }
    
    public function destroy():Void {
        super.destroy();
    }
}

Stores position and size of a rectangle (or square).

Summary

Constructor

Rectangle

Instance properties

Instance properties inherited from BaseShape

$height $width $x $y

Instance properties inherited from CoreObject

$instanceDescription

Instance methods

getX2
setX2
getY2
setY2
getPerimeter
getArea
containsPoint
equals
clone
destroy

Instance methods inherited from BaseShape

clone containsPoint destroy equals getArea getCenterPoint getHeight getPerimeter getPosition getWidth getX getY setHeight setPosition setWidth setX setY

Instance methods inherited from CoreObject

$setClassDescription destroy toString

Constructor

Rectangle

function Rectangle (x:Number, y:Number, width:Number, height:Number)

Creates new rectangle object.

Parameters:

x :

The horizontal position of the rectangle.

y :

The vertical position of the rectangle.

width :

Width of the rectangle.

height:

[optional] Height of the rectangle. If undefined assumes height matches width (Creates square).

Instance methods

clone

function clone () : Rectangle

Returns:

A new rectangle object with the same values as this rectangle.

containsPoint

function containsPoint (pointObject:Point) : Boolean

Overrides:

BaseShape.containsPoint

destroy

function destroy () : Void

Overrides:

BaseShape.destroy

equals

function equals (rectangleObject:Rectangle) : Boolean

Determines whether the rectangle specified in the rectangleObject parameter is equal to this rectangle object.

Parameters:

rectangleObject:

A defined Rectangle object.

getArea

function getArea () : Number

Overrides:

BaseShape.getArea

getPerimeter

function getPerimeter () : Number

Overrides:

BaseShape.getPerimeter

getX2

function getX2 () : Number

Returns:

The right X position of the rectangle.

getY2

function getY2 () : Number

Returns:

The bottom Y position of the rectangle.

setX2

function setX2 (x:Number) : Void

Sets the right position of the rectangle.

Parameters:

The right X position of the rectangle.

setY2

function setY2 (y:Number) : Void

Sets the bottom position of the rectangle.

Parameters:

The bottom Y position of the rectangle.